Touch 在 Windows 下的简单实现

JustYY.com 小赖子的英国生活和资讯

9 years ago

touch 在LINUX下是个很常用的命令行工具. 主要用途就是改变文件时间或者创建一个空的文件.

touch

WINDOWS 本身是没有这个工具的当然你通过安装 git, cygwin 等软件的时候会带有这个小工具. 其实下面的批处理编程就可以很简单的实现 touch 的主要功能 (除了不能指定文件时间之外)

@echo off
:: Touch 在 Windows 下的简单实现
:: https://helloacm.com
 
setlocal
set CreateFiles=True
 
:start
    if %1.==. goto :end
    if "%1"=="-c" (
        set CreateFiles=False
        shift
        goto :start
    )
    if exist "%1" (
        copy /b "%1" +,  > nul
    ) else (
        if "%CreateFiles%"=="True" (
            type nul > "%1" 
        )       
    )
    shift
    goto start
 
:end
endlocal

@echo off
:: Touch 在 Windows 下的简单实现
:: https://helloacm.com

setlocal
set CreateFiles=True

:start
	if %1.==. goto :end
	if "%1"=="-c" (
		set CreateFiles=False
		shift
		goto :start
	)
	if exist "%1" (
		copy /b "%1" +,  > nul
	) else (
		if "%CreateFiles%"=="True" (
			type nul > "%1"	
		)		
	)
	shift
	goto start

:end
endlocal

可以同时 touch 多个文件 Share on X

touch 1 2 3 4

如果不想文件被创建可以指定 -c 开关.

touch -c sample

这个 copy /b “%1” +, > nul 是这个工具的核心用于更新文件时间而不改变文件内容.
type nul > “%1” 命令将会创建一个空文件或者清空一个文件.
shift 会把所有的命令行参数往左移一位这样第一个参数就变成第二个参数第二个参数就变成第三个参数以此类推 (最多9个参数)
setlocal 和 endlocal 定义了局部变量的范围.

英文: https://helloacm.com/simple-touch-implementation-in-windows-batch-programming/

github 代码